'--------------------------------------------------------------------------+
' IMAGES FOLDER CONTAINING THE FILES TO BE RENAMED ( NO TRAILING SLASH )

sImageFolder = "C:\MY_MAP_IMAGES"

'--------------------------------------------------------------------------+

Function String_Regex_Replace(sText, sPattern, sReplace)

    Set oRegEx = CreateObject("VBScript.RegExp")
    oRegEx.Pattern = sPattern
    oRegEx.IgnoreCase = False
    oRegEx.Global = True
    String_Regex_Replace = oRegEx.Replace(sText, sReplace)
    Set oRegEx = Nothing

End Function

'--------------------------------------------------------------------------+

Function Rename_Files(sPath)

  Set oFolder = oFSO.GetFolder(sPath)
  Set oSubFolders = oFolder.SubFolders

  For Each oSubFolder In oSubFolders
    Rename_Files(oSubFolder.Path)
  Next
  
  Set oFiles = oFolder.Files

  For Each oFile in oFiles

    sFileName = LCase(oFile.Name)
    sFileName = String_Regex_Replace(sFileName, "[^a-z0-9_.]", "_")
  
    If sFileName <> oFile.Name Then
      If oFSO.FileExists(sPath & "\" & sFileName) = False Then
        oFile.Move sPath & "\" & sFileName
      End If
    End If

  Next

  Set oFiles = Nothing
  Set oFolder = Nothing
  Set oSubFolders = Nothing

End Function

'--------------------------------------------------------------------------+

Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oShell = CreateObject("WScript.Shell")
Rename_Files(sImageFolder)
oShell.Popup "FINISHED"
Set oFSO = Nothing
Set oShell = Nothing

'--------------------------------------------------------------------------+